home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Merciful 2
/
Merciful - Disc 2.iso
/
software
/
h
/
hypercacheii.dms
/
hypercacheii.adf
/
Install_HyperCache
< prev
next >
Wrap
Text File
|
1994-08-24
|
2KB
|
75 lines
; script to install HyperCache
; Should be run from WorkBench by double-clicking on the icon
; Ask where to install HyperCache 2
(set @default-dest (askdir
(prompt "Please select where to install HyperCache 2. A directory "
"will be created.")
(default @default-dest)
(help "A directory will be created under the one you select. "
"HyperCache 2 will then be installed into this directory."))
)
(set @default-dest (tackon @default-dest "HyperCache2"))
; Create HyperCache 2 directory
(message "HyperCache 2 will be installed in " @default-dest)
(makedir @default-dest
(infos)
(help "If you proceed, the specified directory will be "
"created, and HyperCache 2 installed into it.")
)
; Copy across all the necessary files
(copyfiles
(prompt "Copy HyperCache 2")
(help "HyperCache 2 will now be copied to your system")
(source "HyperCache2:")
(dest @default-dest)
(pattern "~(#?.info)")
(infos)
(confirm)
)
; Copy the one library used
(copylib
(prompt "Install the rexxhost.library?")
(source "HyperCache2:Libs/rexxhost.library")
(dest "Libs:")
)
; See if HyperCache 2 should be started at boot time
(if (= 0 (askchoice
(prompt "Should HyperCache 2 be started at boot time?")
(help "If you select to start HyperCache 2 at boot time, "
"then HyperCache 2 will be copied to your WBStartup "
"drawer, otherwise no action will be taken.")
(choices "Yes" "No")
(default 0)))
(
; Ask if the user has a 68000 or a 68020
(set answer (askchoice
(prompt "What processor does your Amiga have?")
(help "A standard A500, A600, A1000 and the A2000 has a 68000, "
"so select the 68000 option if you have one of these "
"machines.\n"
"A standard A1200, A2500, A3000 and the A4000 "
"has a 68020 or better, so select the 68020 option "
"if you have one of these machines.")
(choices "68000" "68020 or better")
(default 0)
))
; Copy the file to the WBStartup drawer
(if (= answer 0) (set file "HyperCache.68000") (set file "HyperCache.68020"))
(copyfiles
(source (tackon @default-dest file))
(dest "SYS:WBStartup")
(infos))
)
)
; Run the HyperCache 2 config program
(message "HyperCachePrefs will now be started so that you can "
"configure HyperCache 2.")
(run (tackon @default-dest "HyperCachePrefs"))